Party coding 2 by Řrřola

Party coding 2 by Řrřola [web]

screenshot added by Pirx on 2010-09-12 14:53:17

platform :	MS-Dos MS-Dos
type :	256b 256b
release date :	september 2010
release party :	Function 2010
compo :	pc 256b
ranked :	2nd

popularity : 57%

57%

0.93

alltime top: #11045

rrrola [Code]

added on the 2010-09-12 14:49:13 by diver

popularity helper

increase the popularity of this prod by spreading this URL:

or via: facebook twitter pinterest tumblr bluesky threads

comments

pretty polys

rulez added on the 2010-09-12 14:55:23 by bfx

download => 404

added on the 2010-09-12 14:57:21 by vibrator

Ah. File got moved.

This one runs nicely in JPS. Sweet anti-alias!

rulez added on the 2010-09-12 15:02:50 by vibrator

If it comes to blur and lines, Mixer still number 1.

rulez added on the 2010-09-12 15:10:20 by Pirx

still nice for 256b!

rulez added on the 2010-09-12 15:13:17 by diver

Source code:

Code:

; Party coding 2 (done at Function 2010 in exactly 100 minutes)

;Set graphics mode and backbuffer
  mov  al,13h
  int  10h
  add  dh,al
  mov  ds,dx
  push 0A000h
  pop  es

;Randomize point positions and directions (LCG)
R imul bx,21
  inc  bx
  push bx
  or   sp,sp
  js   R

;Awesome gradient palette (green-blue-red-yellow-white)
  mov  dx,03C8h
  out  dx,al
  inc  dx
P pusha
  shr  al,2
Q out  dx,al
  adc  al,al
  sub  al,37
  imul al
  shr  ax,7
  inc  di
  jpe  Q
  popa
  inc  ax
  jnz  P

  xor  cx,cx

;Main loop: animate 50 points
M mov  bp,-8*50

;Update coordinate, bounce from edges (-8000, 7FFF)
N movsx ax,byte[bp+2]
  add  [bp],ax
  jno  O
  sub  [bp],ax
  not  byte[bp+2]
O test bp,4
  jz   Z

;Draw a line between successive points
  push word[bp-4]
  push word[bp]
  pusha

;bx,si = difference/256
  mov  bx,[bp+4]
  mov  ax,[bp-4]
  add  bx,32768
  add  ax,32768
  sub  bx,ax
  rcr  bx,1
  sar  bx,7

  mov  si,[bp+8]
  mov  ax,[bp]
  add  si,32768
  add  ax,32768
  sub  si,ax
  rcr  si,1
  sar  si,7

;Draw them with a small border to prevent overflow
  mov  cx,256
G mov  ax,300
  imul word[bp-4]
  push dx
  mov  ax,187
  imul word[bp]
  imul di,dx,320
  pop  dx
  add  di,dx
  mov  byte[di+320*100+160],255

;Move along the line between the points
  add  [bp-4],bx
  add  [bp],si
  loop G

  popa
  pop  word[bp]
  pop  word[bp-4]

Z add  bp,4
  js   N

;Blur: (1 2 1 : 2 4 2 : 1 2 1) / 16
;Fade out, use fadeout overflow to keep multiple levels stable
  mov  bx,321
B std
A lodsb
  add  [bx+si],al
  rcr  byte[bx+si],1
  mov  al,[bx+si]
  add  al,23
  shr  al,6
  sub  [bx+si],al
  loop A
  neg  bx
  cld
  js   A
  shr  bx,7
  jnz  B

;Copy screen
  xor  si,si
  xor  di,di
  mov  cx,4000h
  rep movsd

;Wait for retrace: 70 fps cap
  mov  dx,3DAh
V in   al,dx
  and  al,8
  jz   V

;Exit on ESC
  in   al,60h
  dec  al
  jnz  M
  int  20h

added on the 2010-09-12 19:38:15 by rrrola

thx! ;)

rulez added on the 2010-09-12 22:59:42 by T$